一、需求
由于表達能力不好，直接上圖。在mssql環境中需要把圖1的表轉化成圖2的表：
圖1 
圖2
二、分析
圖3
2.1創建表
復制代碼 代碼如下:
create table #tb
(ID int primary key,
Class nvarchar(max),
[Subject] nvarchar(max),
Score int)
insert into #tb values(1,'一(1)班','語文','92')
insert into #tb values(2,'一(1)班','數學','91')
insert into #tb values(3,'一(1)班','英語','93')
insert into #tb values(4,'一(2)班','數學','94')
insert into #tb values(5,'一(2)班','語文','95')
insert into #tb values(6,'一(2)班','英語','96')
insert into #tb values(7,'一(3)班','數學','94')
insert into #tb values(8,'一(3)班','語文','96')
insert into #tb values(9,'一(3)班','英語','97')
select * from #tb
2.2把圖3中的第一張表轉化為第二張表
復制代碼 代碼如下:
select [Subject], [一(1)班]=[Score]
,[一(2)班]=[Score]
,[一(3)班]=[Score]
from #tb
2.3把圖3中的第二張表轉化為第三張表
復制代碼 代碼如下:
--觀察第二張表，表顯然很多成績是錯誤的，所以要消除錯誤
--消除錯誤的方法:先把錯誤的成績設置為0，然后每一行取最大的數作為成績，并按照科目來分組顯示
select subject,[一(1)班]=case when [Class]='一(1)班' then [Score] else 0 end
,[一(2)班]= case when [Class]='一(2)班' then [Score] else 0 end
,[一(3)班]=case when [Class]='一(3)班' then [Score] else 0 end
from #tb
2.4 把圖3中的第三張表轉化為第四張表
復制代碼 代碼如下:
select subject, [一(1)班]=max( case when [Class]='一(1)班' then [Score] else 0 end)
,[一(2)班]=max( case when [Class]='一(2)班' then [Score] else 0 end)
,[一(3)班]=max( case when [Class]='一(3)班' then [Score] else 0 end)
from #tb group by subject
2.5簡化上面的寫法
復制代碼 代碼如下:
declare @s nvarchar(4000)
set @s=''
Select @s=@s+','+quotename(Class)+'=max( case when [Class]='+quotename(Class,'''')+' then [Score] else 0 end)'
from #tb group by Class
--print @s
exec('select [Subject]'+@s+' from #tb group by [Subject]')
三、簡化分析和需求延伸
3.1簡化分析
上面的簡化，對于菜鳥級的我，理解著還是非常吃力的，所以我是在知道答案后，用 print @s一步一步的去分析的，特別是在select @s=@s+.....的時間，在這里我找到了一種把單列數據連接成字符串的方法。
圖4
3.2需求延伸
或許上面的需求太簡單，那么我們現在引出復雜點的需求，動態獲取班級的成績，比如我們的需求可能是列出部分班級的成績，代碼如下：
復制代碼 代碼如下:
declare @s nvarchar(4000)
set @s=''
Select @s=@s+','+quotename(Class)+'=max( case when [Class]='+quotename(Class,'''')+' then [Score] else 0 end)'
from #tb
where Class in(你想要的班級)
group by Class
--print @s
exec('select [Subject]'+@s+' from #tb group by [Subject]')
四、總結
本文主要實現表的另外一種顯示，通常用于動態顯示數據的例子中。難點在于分析過程和一些基本的sql語法。
